home *** CD-ROM | disk | FTP | other *** search
/ Fritz: All Fritz / All Fritz.zip / All Fritz / FILES / AVIATHER / WEATHR51.LZH / WX51.BAS < prev    next >
BASIC Source File  |  1987-01-04  |  23KB  |  556 lines
  1. 10 REM
  2. 20 REM      WEATHER FORECAST PROGRAM by Phil Baughn
  3. 30 REM
  4. 40 REM      This software program is distributed as "SHAREWARE".  You may
  5. 50 REM      feel free to copy and revise it as you like as long as you do
  6. 60 REM      not alter or remove the credit information in the program. If
  7. 70 REM      you find that you have made some significant improvements and
  8. 80 REM      additions to this package, please upload them to my attention
  9. 90 REM      either at The MAILROOM RBBS or to Compuserve; User#76044,1535.
  10. 100 REM      Enjoy!    Phil Baughn
  11. 110 REM
  12. 120 REM     Mailing address:          The MAILROOM RBBS-PC
  13. 130 REM                               attn.  Phil Baughn
  14. 140 REM                               2050 Idle Hour Center
  15. 150 REM                               Lexington, KY  40502
  16. 160 REM                               Data:  (606)293-5119
  17. 170 REM                               Voice: (606)268-0206
  18. 180 REM
  19. 190 REM     Special Credit to Mssrs. Bernard N. Meisner and Leon F. Graves
  20. 200 REM     who developed the Heat Index / Apparent Temperature Formula.
  21. 210 REM
  22. 220 REM     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  23. 230 REM
  24. 240 REM     BELOW TURNS KEYS OFF, SELECTS COLOR OR MONO, TURNS CAPS ON
  25. 250 REM
  26. 260 DEF SEG=0:POKE 1047,96:DEF SEG
  27. 270 KEY OFF:CLS:LOCATE 10,23:INPUT "Do you want Color? (Y)es or (N)o";CLRANS$
  28. 280 IF LEFT$(CLRANS$,1)="Y" OR LEFT$(CLRANS$,1)="y" THEN CLRT$="Y":GOTO 330
  29. 290 IF LEFT$(CLRANS$,1) <> "N" AND LEFT$(CLRANS$,1) <> "n" THEN GOTO 270
  30. 300 CLRT$ = " "
  31. 310 REM
  32. 320 REM
  33. 330 GOSUB 1040
  34. 340 REM     GET WELCOME SCREEN AND CREDITS IN ABOVE LINE
  35. 350 REM     GET MASTER WELCOME DOCUMENT IN FOLLOWING LINE
  36. 360 GOSUB 1330
  37. 370 REM
  38. 380 REM     PRINT MAIN MENU
  39. 390 REM
  40. 400 CLS:IF CLRT$ = "Y" THEN COLOR 14
  41. 410 LOCATE 9,20:PRINT "1 - WEATHER FORECAST PROGRAM"
  42. 420 IF CLRT$ = "Y" THEN COLOR 11
  43. 430 LOCATE 11,20:PRINT "2 - WIND CHILL CALCULATION"
  44. 440 IF CLRT$ = "Y" THEN COLOR 12
  45. 450 LOCATE 13,20:PRINT "3 - TEMPERATURE HUMIDITY INDEX"
  46. 460 IF CLRT$ = "Y" THEN COLOR 13
  47. 470 LOCATE 15,20:PRINT "4 - HEAT INDEX CALCULATION"
  48. 480 IF CLRT$ = "Y" THEN COLOR 14
  49. 490 LOCATE 17,20:PRINT "5 - DEW POINT CALCULATION"
  50. 500 IF CLRT$ = "Y" THEN COLOR 9
  51. 510 LOCATE 5,5:INPUT "ENTER THE NUMBER OF THE WEATHER PROGRAM WHICH YOU WISH TO RUN  ";CHOICE
  52. 520 REM
  53. 530 REM     GET FORCASTING SUNROUTINE
  54. 540 REM
  55. 550 IF CHOICE=1 THEN GOSUB 1650 ELSE GOTO 600
  56. 560 GOTO 790
  57. 570 REM
  58. 580 REM     GET WIND CHILL SUBROUTINE
  59. 590 REM
  60. 600 IF CHOICE=2 THEN GOSUB 3290 ELSE GOTO 650
  61. 610 GOTO 790
  62. 620 REM
  63. 630 REM     GET TEMP-HUMIDITY SUBROUTINE
  64. 640 REM
  65. 650 IF CHOICE=3 THEN GOSUB 4710 ELSE GOTO 700
  66. 660 GOTO 790
  67. 670 REM
  68. 680 REM     GET HEAT INDEX SUBROUTINE
  69. 690 REM
  70. 700 IF CHOICE=4 THEN GOSUB 3610 ELSE GOTO 750
  71. 710 GOTO 790
  72. 720 REM
  73. 730 REM     GET DEW POINT SUBROUTINE
  74. 740 REM
  75. 750 IF CHOICE=5 THEN GOSUB 5230 ELSE GOTO 400
  76. 760 REM
  77. 770 REM     LOOP OR QUIT
  78. 780 REM
  79. 790 LOCATE 24,14:INPUT "DO YOU WISH TO DO A DIFFERENT CALCULATION (Y/N)";D$
  80. 800 REM
  81. 810 REM     LOOP
  82. 820 REM
  83. 830 IF D$="Y" OR D$="y" THEN GOTO 400
  84. 840 REM
  85. 850 REM     QUIT WITH EPILOG SCREEN AND RESET IF CLRT$="Y" THEN COLORS TO NORMAL
  86. 860 REM     ALSO PLACE CAPS AND NUMBERS LOCK KEYS BACK TO OFF STATUS
  87. 870 REM
  88. 880 IF CLRT$ = "Y" THEN COLOR 12,0,0
  89. 890 CLS:LOCATE 9,23:PRINT "I hope you enjoyed WEATHER and"
  90. 900 LOCATE 11,21:PRINT "that your forecast was a good one."
  91. 910 LOCATE 15,20:PRINT "Let us here from you on The MAILROOM"
  92. 920 LOCATE 17,18:PRINT "Data (606)293-5119 - 2400 Baud Supported"
  93. 930 LOCATE 19,37:PRINT "- Phil Baughn"
  94. 940 DEF SEG=0:POKE 1047,0:DEF SEG
  95. 950 IF CLRT$ = "Y" THEN COLOR 7,0,0
  96. 960 LOCATE 24,1
  97. 970 END
  98. 980 REM     ~~~~~~~~~~~~~~PROGRAM ENDS HERE~~~~~~~~~~~~~~
  99. 990 REM
  100. 1000 REM     ~~~~~~~~SUBROUTINE MODULES BEGIN HERE~~~~~~~~
  101. 1010 REM
  102. 1020 REM     WELCOME SCREEN AND CREDITS SUBROUTINE
  103. 1030 REM
  104. 1040 CLS
  105. 1050 WIDTH 80:IF CLRT$ = "Y" THEN COLOR 11,0
  106. 1060 LOCATE 5,5:PRINT CHR$(201):LOCATE 5,75:PRINT CHR$(187)
  107. 1070 LOCATE 20,5:PRINT CHR$(200):LOCATE 20,75:PRINT CHR$(188)
  108. 1080 FOR N=6 TO 19
  109. 1090 LOCATE N,5:PRINT CHR$(186)
  110. 1100 LOCATE N,75:PRINT CHR$(186)
  111. 1110 NEXT N
  112. 1120 FOR N=6 TO 74
  113. 1130 LOCATE 5,N:PRINT CHR$(205)
  114. 1140 LOCATE 20,N:PRINT CHR$(205)
  115. 1150 NEXT N
  116. 1160 IF CLRT$ = "Y" THEN COLOR 13,0
  117. 1170 LOCATE 7,31:PRINT "WEATHER FORCASTING"
  118. 1180 LOCATE 9,28:PRINT "DEVELOPED FOR THE IBM-PC"
  119. 1190 LOCATE 10,39:PRINT "BY"
  120. 1200 LOCATE 11,35:PRINT "PHIL BAUGHN"
  121. 1210 LOCATE 13,14:PRINT "Special Thanks For Module Improvements To Sean Gayle,"
  122. 1220 LOCATE 14,11:PRINT "John Fleming, & Brad James - Meteorologist, WKYT, Lexington"
  123. 1230 LOCATE 16,20:PRINT "Distributed Through The MAILROOM RBBS-PC"
  124. 1240 LOCATE 17,29:PRINT "In Lexington, Kentucky"
  125. 1250 LOCATE 18,22:PRINT "(606)293-5119   24 Hours - 2400 Baud"
  126. 1260 LOCATE 19,21:PRINT "Latest Revision [ 5.1 ];  January 1987"
  127. 1270 FOR N=1 TO 9999
  128. 1280 NEXT N
  129. 1290 RETURN
  130. 1300 REM
  131. 1310 REM     MAIN WELCOME DOCUMENT SUBROUTINE
  132. 1320 REM
  133. 1330 IF CLRT$ = "Y" THEN COLOR 14,1,1
  134. 1340 CLS
  135. 1350 PRINT "  "
  136. 1360 PRINT "  "
  137. 1370 PRINT "    This  program  will provide  you with a very good forcast providing"
  138. 1380 PRINT "    you supply the correct  information  as to barometric  pressure and"
  139. 1390 PRINT "    wind direction.  This method has been used  for ages  by  sailors &"
  140. 1400 PRINT "    the tables  themselves can still be found in  almost  all  editions"
  141. 1410 PRINT "    of The Farmers Almanac."
  142. 1420 PRINT " "
  143. 1430 PRINT "    The other four programs which are included at present;  Wind Chill,"
  144. 1440 PRINT "    Dew Point, Temp/Humidity, & Heat Index; can be especially important"
  145. 1450 PRINT "    when working outdoors.  Wind Chill tells you the true  FEEL  of the"
  146. 1460 PRINT "    temperature  after the wind has it's effect.   It's not always safe"
  147. 1470 PRINT "    to simply  look  at the outdoor thermometer!  Humidity also effects"
  148. 1480 PRINT "    the temperature.   Higher humidity  levels  cause it to effect your"
  149. 1490 PRINT "    body as if it were hotter than the thermometer states."
  150. 1500 PRINT "  "
  151. 1510 PRINT "    Enjoy the program,   please pass along any  improvements  which you"
  152. 1520 PRINT "    may develop  or  additional  modules  which will fit well into  the"
  153. 1530 PRINT "    menu.   Listing  the  programs, lines 1-200, [ ie- LIST -200 ] will"
  154. 1540 PRINT "    provide you with more detailed contact information."
  155. 1550 PRINT "  "
  156. 1560 PRINT "  "
  157. 1570 PRINT "    Press any key when ready..."
  158. 1580 IF INKEY$ ="" GOTO 1580
  159. 1590 IF CLRT$ = "Y" THEN COLOR 7,0,0
  160. 1600 CLS
  161. 1610 RETURN
  162. 1620 REM
  163. 1630 REM     WIND-BAROMETER FORECASTING SUBROUTINE
  164. 1640 REM
  165. 1650 CLS:IF CLRT$ = "Y" THEN COLOR 14
  166. 1660 LOCATE 2,25:PRINT "WEATHER FORECAST PROGRAM"
  167. 1670 IF CLRT$ = "Y" THEN COLOR 5
  168. 1680 LOCATE 4,32:PRINT DATE$:LOCATE 5,33:PRINT TIME$
  169. 1690 IF CLRT$ = "Y" THEN COLOR 3,0,0
  170. 1700 KEY OFF:LOCATE 7,12
  171. 1710 INPUT "ENTER CURRENT BAROMETRIC PRESSURE                  ";CBP
  172. 1720 IF CBP<25 THEN 1700
  173. 1730 IF CBP>35 THEN 1700
  174. 1740 LOCATE 8,12
  175. 1750 INPUT "WIND DIRECTION IS CURRENTLY FROM THE               ";PWD$
  176. 1760 IF PWD$="SW" THEN 1770 ELSE 1800
  177. 1770 LOCATE 9,12
  178. 1780 INPUT "PREVIOUS WIND DIRECTION WAS FROM THE               ";PWD$
  179. 1790 GOTO 1930
  180. 1800 IF PWD$="SE" THEN 1810 ELSE 1840
  181. 1810 LOCATE 9,12
  182. 1820 INPUT "PREVIOUS WIND DIRECTION WAS FROM THE               ";PWD$
  183. 1830 GOTO 2010
  184. 1840 IF PWD$="S" THEN 1880 ELSE 1850
  185. 1850 IF PWD$="N" THEN 1880 ELSE 1860
  186. 1860 IF PWD$="NW" THEN 1880 ELSE 1870
  187. 1870 IF PWD$="NE" THEN 1880 ELSE 2090
  188. 1880 LOCATE 18,23
  189. 1890 IF CLRT$ = "Y" THEN COLOR 9
  190. 1900 PRINT "NO IMMEDIATE CHANGE IS FORECAST"
  191. 1910 IF CLRT$ = "Y" THEN COLOR 7,0,0
  192. 1920 GOTO 3220
  193. 1930 IF PWD$="S" THEN 1950 ELSE 1940
  194. 1940 IF PWD$="NW" THEN 1970 ELSE 1990
  195. 1950 PWD$="M"
  196. 1960 GOTO 2140
  197. 1970 PWD$="N"
  198. 1980 GOTO 2140
  199. 1990 PWD$="O"
  200. 2000 GOTO 2140
  201. 2010 IF PWD$="NE" THEN 2030 ELSE 2020
  202. 2020 IF PWD$="S" THEN 2050 ELSE 2070
  203. 2030 PWD$="P"
  204. 2040 GOTO 2140
  205. 2050 PWD$="Q"
  206. 2060 GOTO 2140
  207. 2070 PWD$="R"
  208. 2080 GOTO 2140
  209. 2090 IF PWD$="E" THEN 2110 ELSE 2100
  210. 2100 IF PWD$="W" THEN 2130
  211. 2110 PWD$="S"
  212. 2120 GOTO 2140
  213. 2130 PWD$="T"
  214. 2140 IF CLRT$ = "Y" THEN COLOR 4
  215. 2150 LOCATE 13,12:PRINT "WIND CONDITION CODE IS ",PWD$;
  216. 2160 IF CLRT$ = "Y" THEN COLOR 3,0,0
  217. 2170 IF CBP>30.01 THEN 2340 ELSE 2180
  218. 2180 IF CBP<29.81 THEN 2490 ELSE 2190
  219. 2190 LOCATE 10,12
  220. 2200 INPUT "IS PRESSURE RISING (R), FALLING (F), OR STEADY (S) ";BM$
  221. 2210 IF BM$="F" THEN 2220 ELSE 2290
  222. 2220 LOCATE 11,12
  223. 2230 INPUT "IS IT FALLING RAPIDLY (R) OR SLOWLY (S)            ";BM$
  224. 2240 IF BM$="R" THEN 2250 ELSE 2270
  225. 2250 BM$="C6"
  226. 2260 GOTO 2560
  227. 2270 BM$="C5"
  228. 2280 GOTO 2560
  229. 2290 IF BM$="R" THEN 2300 ELSE 2320
  230. 2300 BM$="C7"
  231. 2310 GOTO 2560
  232. 2320 BM$="C0"
  233. 2330 GOTO 2560
  234. 2340 LOCATE 10,12
  235. 2350 INPUT "IS PRESSURE RISING (R), FALLING (F), OR STEADY (S) ";BM$
  236. 2360 IF BM$="F" THEN 2370 ELSE 2440
  237. 2370 LOCATE 11,12
  238. 2380 INPUT "IS IT FALLING RAPIDLY (R) OR SLOWLY (S)            ";BM$
  239. 2390 IF BM$="R" THEN 2400 ELSE 2420
  240. 2400 BM$="C4"
  241. 2410 GOTO 2560
  242. 2420 BM$="C3"
  243. 2430 GOTO 2560
  244. 2440 IF BM$="S" THEN 2450 ELSE 2470
  245. 2450 BM$="C1"
  246. 2460 GOTO 2560
  247. 2470 BM$="C2"
  248. 2480 GOTO 2560
  249. 2490 LOCATE 10,12
  250. 2500 INPUT "IS THE PRESSURE RISING (R) OR FALLING (F)          ";BM$
  251. 2510 IF BM$="R" THEN 2520 ELSE 2540
  252. 2520 BM$="C8"
  253. 2530 GOTO 2560
  254. 2540 BM$="C9"
  255. 2550 GOTO 2560
  256. 2560 IF CLRT$ = "Y" THEN COLOR 4
  257. 2570 LOCATE 14,12:PRINT "BAROMETRIC CODE IS ",BM$
  258. 2580 IF CLRT$ = "Y" THEN COLOR 3,0,0
  259. 2590 IF PWD$="O" THEN 1880
  260. 2600 IF PWD$="R" THEN 1880
  261. 2610 LOCATE 17,18:PRINT "PLEASE WAIT - FORECAST BEING COMPUTED"
  262. 2620 FOR X=1 TO 3200:NEXT X
  263. 2630 LOCATE 17,18:PRINT "                                                 "
  264. 2640 IF PWD$="T" AND BM$="C8" THEN 2840
  265. 2650 IF PWD$="M" AND BM$="C7" THEN 2860
  266. 2660 IF PWD$="Q" AND BM$="C3" THEN 2890
  267. 2670 IF PWD$="Q" AND BM$="C4" THEN 2910
  268. 2680 IF PWD$="Q" AND BM$="C9" THEN 2930
  269. 2690 IF PWD$="P" AND BM$="C3" THEN 2960
  270. 2700 IF PWD$="P" AND BM$="C4" THEN 2980
  271. 2710 IF PWD$="P" AND BM$="C5" THEN 2990
  272. 2720 IF PWD$="P" AND BM$="C6" THEN 3010
  273. 2730 IF PWD$="P" AND BM$="C9" THEN 2930
  274. 2740 IF PWD$="S" AND BM$="C3" THEN 3040
  275. 2750 IF PWD$="S" AND BM$="C4" THEN 3070
  276. 2760 IF PWD$="S" AND BM$="C9" THEN 3120
  277. 2770 IF PWD$="N" AND BM$="C1" THEN 3150
  278. 2780 IF PWD$="N" AND BM$="C2" THEN 3180
  279. 2790 IF PWD$="N" AND BM$="C3" THEN 3200
  280. 2800 IF PWD$="N" AND BM$="C7" THEN 2860
  281. 2810 LOCATE 17,20:IF CLRT$ = "Y" THEN COLOR 13
  282. 2820 PRINT "WIND INCREASING; RAIN WITHIN 12 HOURS":GOTO 3220
  283. 2830 GOTO 1880
  284. 2840 LOCATE 17,30:IF CLRT$ = "Y" THEN COLOR 13
  285. 2850 PRINT "CLEARING AND COLDER":GOTO 3220
  286. 2860 LOCATE 17,20:IF CLRT$ = "Y" THEN COLOR 13
  287. 2870 PRINT "CLEARING WITHIN A FEW HOURS/"
  288. 2880 LOCATE 19,20:PRINT "FAIR FOR SEVERAL DAYS":GOTO 3220
  289. 2890 LOCATE 17,30:IF CLRT$ = "Y" THEN COLOR 13
  290. 2900 PRINT "RAIN WITHIN 24 HOURS":GOTO 3220
  291. 2910 LOCATE 17,20:IF CLRT$ = "Y" THEN COLOR 13
  292. 2920 PRINT "WIND INCREASING; RAIN WITHIN 24 HOURS":GOTO 3220
  293. 2930 LOCATE 17,15:IF CLRT$ = "Y" THEN COLOR 15
  294. 2940 PRINT "SEVERE STORM IMMIMENT, FOLLOWED WITHIN 24 HOURS"
  295. 2950 LOCATE 19,15:PRINT "BY CLEARING. IN WINTER, COLDER TEMPERATURES.":GOTO 3220
  296. 2960 LOCATE 17,30:IF CLRT$ = "Y" THEN COLOR 13
  297. 2970 PRINT "RAIN WITHIN 12 TO 18 HOURS":GOTO 3220
  298. 2980 LOCATE 17,20:IF CLRT$ = "Y" THEN COLOR 13
  299. 2990 LOCATE 17,20:IF CLRT$ = "Y" THEN COLOR 13
  300. 3000 PRINT "RAIN WILL CONTINUE FOR 1 TO 2 DAYS":GOTO 3220
  301. 3010 LOCATE 17,15:IF CLRT$ = "Y" THEN COLOR 13
  302. 3020 PRINT "RAIN, WITH HIGH WIND, FOLLOWED WITHIN 36 HOURS BY"
  303. 3030 LOCATE 19,15:PRINT "CLEARING. IN WINTER - COLDER TEMPERATURES.":GOTO 3220
  304. 3040 LOCATE 17,15:IF CLRT$ = "Y" THEN COLOR 13
  305. 3050 PRINT "SUMMER - LIGHT WINDS; RAIN MAY NOT FALL FOR"
  306. 3060 LOCATE 19,15:PRINT "SEVERAL DAYS.  WINTER - RAIN WITHIN 24 HOURS":GOTO 3220
  307. 3070 LOCATE 17,15:IF CLRT$ = "Y" THEN COLOR 13
  308. 3080 PRINT "SUMMER RAIN PROBABLE 12/24 HOURS.  WINTER"
  309. 3090 LOCATE 19,15:PRINT "RAIN OR SNOW, INCREASING WIND; BAD WEATHER"
  310. 3100 LOCATE 21,15:PRINT "OFTEN SETS IN WHEN BAROMETER BEGINS TO FALL AND"
  311. 3110 LOCATE 23,15:PRINT "WINDS SET IN FROM THE NORTHEAST.":GOTO 3220
  312. 3120 LOCATE 17,15:IF CLRT$ = "Y" THEN COLOR 15
  313. 3130 PRINT "SEVERE NORTHEAST GALE AND HEAVY PRECIPITATION,"
  314. 3140 LOCATE 19,15:PRINT "IN WINTER - HEAVY SNOW FOLLOWED BY A COLD WAVE":GOTO 3220
  315. 3150 LOCATE 17,20:IF CLRT$ = "Y" THEN COLOR 13
  316. 3160 PRINT "CONTINUED FAIR WEATHER WITH"
  317. 3170 LOCATE 19,20:PRINT "NO DECIDED TEMPERATURE CHANGE":GOTO 3220
  318. 3180 LOCATE 17,20:IF CLRT$ = "Y" THEN COLOR 13
  319. 3190 PRINT "FAIR, FOLLOWED WITHIN 2 DAYS BY RAIN":GOTO 3220
  320. 3200 LOCATE 17,15:IF CLRT$ = "Y" THEN COLOR 13
  321. 3210 PRINT "FAIR FOR 2 DAYS WITH SLOWLY RISING TEMPERATURES"
  322. 3220 IF CLRT$ = "Y" THEN COLOR 7,0,0
  323. 3230 LOCATE 24,17:INPUT "DO YOU WISH TO RUN ANOTHER FORECAST (Y/N)";L$
  324. 3240 IF L$="Y" OR L$="y" THEN GOTO 1650
  325. 3250 RETURN
  326. 3260 REM
  327. 3270 REM     WIND CHILL SUBROUTINE
  328. 3280 REM
  329. 3290 CLS:IF CLRT$ = "Y" THEN COLOR 11
  330. 3300 LOCATE 2,27:PRINT "WIND CHILL CALCULATION"
  331. 3310 IF CLRT$ = "Y" THEN COLOR 5
  332. 3320 LOCATE 4,34:PRINT DATE$:LOCATE 5,35:PRINT TIME$
  333. 3330 IF CLRT$ = "Y" THEN COLOR 3,0,0
  334. 3340 KEY OFF:LOCATE 7,12
  335. 3350 INPUT "ENTER TEMPERATURE IN FAHRENHEIT                    ";T
  336. 3360 LOCATE 8,12
  337. 3370 INPUT "ENTER WIND SPEED IN MILES PER HOUR                 ";V
  338. 3380 T1=T:V=(V*1609.35)/(3600):TC=33-((T-32)*(5/9))
  339. 3390 H=(10.45+(SQR(V)*10)-V)*TC:X=H-506.784
  340. 3400 IF X<0 THEN X1=T1:GOTO 3520
  341. 3410 X1=50-(X/12.3):X1=INT(((X1*10)+5)/10)
  342. 3420 IF CLRT$ = "Y" THEN COLOR 3
  343. 3430 LOCATE 11,19:PRINT "PLEASE WAIT - WIND CHILL BEING COMPUTED"
  344. 3440 FOR ZZ=1 TO 1600:NEXT ZZ
  345. 3450 IF CLRT$ = "Y" THEN COLOR 4
  346. 3460 LOCATE 13,17:PRINT "T1=T:V=(V*1069.35)/3600:TC=33-((T-32)*(5/9))"
  347. 3470 FOR Z=1 TO 800:NEXT Z
  348. 3480 LOCATE 14,20:PRINT "H=(10.45+(SQR(V)*10)-V)*TC:X=H-506.784"
  349. 3490 FOR ZXC=1 TO 800:NEXT ZXC
  350. 3500 LOCATE 15,21:PRINT "X1=50-(X/12.3):X1=INT(((X1*10)+5)/10)"
  351. 3510 FOR ZX=1 TO 1600:NEXT ZX
  352. 3520 IF CLRT$ = "Y" THEN COLOR 13
  353. 3530 LOCATE 19,15:PRINT "WIND CHILL TEMPERATURE = ";X1;"DEGREES FAHRENHEIT"
  354. 3540 IF CLRT$ = "Y" THEN COLOR 7,0,0
  355. 3550 LOCATE 24,19:INPUT "RUN ANOTHER WIND CHILL FACTOR (Y/N)";L$
  356. 3560 IF L$="Y" OR L$="y" THEN GOTO 3290
  357. 3570 RETURN
  358. 3580 REM
  359. 3590 REM     HEAT INDEX SUBROUTINE
  360. 3600 REM
  361. 3610 CLS:IF CLRT$ = "Y" THEN COLOR 11
  362. 3620 LOCATE 2,27:PRINT "HEAT INDEX CALCULATION"
  363. 3630 IF CLRT$ = "Y" THEN COLOR 5
  364. 3640 LOCATE 4,34:PRINT DATE$:LOCATE 5,35:PRINT TIME$
  365. 3650 IF CLRT$ = "Y" THEN COLOR 3,0,0
  366. 3660 KEY OFF:LOCATE 7,11
  367. 3670 INPUT "ENTER THE CURRENT TEMPERATURE IN DEGREES FAHRENHEIT ";TA
  368. 3680 U$="F"
  369. 3690 LOCATE 8,11
  370. 3700 INPUT "ENTER THE RELATIVE HUMIDITY  (`50'= 50% )           ";RH
  371. 3710 IF CLRT$ = "Y" THEN COLOR 9
  372. 3720 LOCATE 11,18:PRINT "PLEASE WAIT - HEAT INDEX BEING COMPUTED"
  373. 3730 FOR ZZ=1 TO 1600:NEXT ZZ
  374. 3740 IF CLRT$ = "Y" THEN COLOR 4
  375. 3750 LOCATE 13,23:PRINT "Heat Index Is Also Refered To"
  376. 3760 FOR Z=1 TO 800:NEXT Z
  377. 3770 LOCATE 14,17:PRINT "As The Apparent Temperature.  See The H/I"
  378. 3780 FOR ZXC=1 TO 800:NEXT ZXC
  379. 3790 LOCATE 15,18:PRINT "Explanation & Danger Table For Details."
  380. 3800 FOR ZX=1 TO 1600:NEXT ZX
  381. 3810 GOSUB 4150
  382. 3820 IF CLRT$ = "Y" THEN COLOR 11
  383. 3830 LOCATE 19,19:PRINT "APPARENT TEMPERATURE = ";APPTEMP;" ";U$
  384. 3840 IF DF<0 THEN GOTO 3860
  385. 3850 GOTO 3870
  386. 3860 LOCATE 20,19:PRINT "SEVERE SULTRINESS..."
  387. 3870 IF CLRT$ = "Y" THEN COLOR 7,0,0
  388. 3880 LOCATE 23,19:INPUT "RUN ANOTHER HEAT INDEX FACTOR (Y/N)";L$
  389. 3890 IF L$="Y" OR L$="y" THEN GOTO 3610
  390. 3900 LOCATE 24,16:INPUT "View H/I  Explanation & Danger Table? (Y/N)";CT$
  391. 3910 IF CT$="N" OR CT$="n" THEN GOTO 4140
  392. 3920 IF CLRT$ = "Y" THEN COLOR 14,1,1
  393. 3930 CLS
  394. 3940 PRINT "  "
  395. 3950 PRINT "       Your Present Calculated Heat Index Value Is" APPTEMP" "U$"."
  396. 3960 PRINT "  "
  397. 3970 PRINT "       When the  Heat Index reaches 130 degrees or higher, Heat"
  398. 3980 PRINT "       Strokes or  Sunstrokes are  HIGHLY likely with continued"
  399. 3990 PRINT "       exposure!   When the  Heat Index  ranges from 105 to 130"
  400. 4000 PRINT "       degrees,  sunstroke, heat exhaustion and heat cramps are"
  401. 4010 PRINT "       likely with  prolonged exposure and/or physical activity."
  402. 4020 PRINT "       Heat Index  ranges between 90 and 105 degrees indicate a"
  403. 4030 PRINT "       possibility  of  heat  cramps and  heat  exhaustion with"
  404. 4040 PRINT "       prolonged  exposure and/or physical activity."
  405. 4050 PRINT "  "
  406. 4060 PRINT "       Program calculations assume an adult, wearing long pants"
  407. 4070 PRINT "       and a  short sleeved shirt,  walking in shade at 3.1 MPH"
  408. 4080 PRINT "       with standard sea level air pressure,  a wind  speed  of"
  409. 4090 PRINT "       5.6 MPH, and a vapor pressure of 1.6kPa.  In effect, the"
  410. 4100 PRINT "       calculations  approximate the temperature  that  current"
  411. 4110 PRINT "       conditions feel like to the average person."
  412. 4120 PRINT "  "
  413. 4130 IF CLRT$ = "Y" THEN COLOR 7,0,0
  414. 4140 RETURN
  415. 4150 TC=TA
  416. 4160 IF U$="F" OR U$="f" THEN TC=(TA-32)*5/9
  417. 4170 ES=6.11*10^((7.567*TC)/(239.7+TC))
  418. 4180 E=.01*RH*ES
  419. 4190 GOTO 4230
  420. 4200 IF DF<0 THEN GOTO 4530
  421. 4210 IF U$="F" OR U$="f" THEN APPTEMP=32+1.8*APPTEMP
  422. 4220 RETURN
  423. 4230 TB=37:PB=5.65:Q=180:RS=.0387
  424. 4240 ZS=.0521:EHC=17.4:PHI2=.84
  425. 4250 R=.124:CHC=11.6:PINF=.1*E
  426. 4260 HER=4.18+.036*TC
  427. 4270 ERA=1/(EHC+HER)
  428. 4280 QV=Q*(.143-.00112*TC-.0168*PINF)
  429. 4290 EZA=.060606/EHC
  430. 4300 HR=3.35+.049*TC
  431. 4310 ARA=1/(CHC+HR)
  432. 4320 AZA=.060606/CHC
  433. 4330 Q2U=((TB-TC)+(PB-PINF)*ERA/(ZS+EZA))/(RS+ERA)
  434. 4340 QJ=(Q-QV-(1-PHI2)*Q2U)/PHI2
  435. 4350 K=(RS+ARA)+(ZS+AZA)/R-((TB-TC)+(PB-PINF)/R)/QJ
  436. 4360 L=(RS+ARA)*(ZS+AZA)
  437. 4370 L=(L-((TB-TC)*(ZS+AZA)+(PB-PINF)*ARA)/QJ)/R
  438. 4380 F=K*K-4*L
  439. 4390 IF F<0 THEN DF=-1
  440. 4400 IF F<0 THEN GOTO 4200
  441. 4410 RF=.5*(-K+SQR(F))
  442. 4420 DF=60*RF
  443. 4430 IF DF<0 THEN GOTO 4200
  444. 4440 W1=.2016
  445. 4450 W2=(1-PHI2)/(RS+ERA)
  446. 4460 W3=PHI2/(RS+RF+ARA)
  447. 4470 W4=159.0984
  448. 4480 W5=37
  449. 4490 W6=4.05*ERA/(ZS+EZA)
  450. 4500 W7=4.05*(RF+ARA)/(ZS+R*RF+AZA)
  451. 4510 APPTEMP=(-W4+W2*(W5+W6)+W3*(W5+W7))/(W1+W2+W3)
  452. 4520 GOTO 4200
  453. 4530 HC=12.3:HR=4.1+.028*TC
  454. 4540 RA=1/(HC+HR):ZA=.060606/HC
  455. 4550 QU=Q-QV
  456. 4560 FOR IT=1 TO 10
  457. 4570 ZS=((PB-PINF)*RA)/(QU*(RS+RA)-(TB-TC))-ZA
  458. 4580 IF ZS<0 THEN ZS=0
  459. 4590 R3=(ZS/600000!)^.2
  460. 4600 C=ABS(RS-R3)
  461. 4610 IF C<=.0001 THEN GOTO 4640
  462. 4620 RS=.5*(RS+R3)
  463. 4630 NEXT IT
  464. 4640 N1=159.0984:N2=37:N3=4.05*RA/(ZS+ZA)
  465. 4650 N4=(RS+RA):N5=.2016
  466. 4660 APPTEMP=(-N1+(N2+N3)/N4)/(N5+1/N4)
  467. 4670 GOTO 4210
  468. 4680 REM
  469. 4690 REM     TEMP-HUMIDITY INDEX SUBROUTINE
  470. 4700 REM
  471. 4710 CLS:IF CLRT$ = "Y" THEN COLOR 12
  472. 4720 LOCATE 2,26:PRINT "TEMPERATURE HUMIDITY INDEX"
  473. 4730 IF CLRT$ = "Y" THEN COLOR 5
  474. 4740 LOCATE 4,34:PRINT DATE$:LOCATE 5,35:PRINT TIME$
  475. 4750 IF CLRT$ = "Y" THEN COLOR 3,0,0
  476. 4760 KEY OFF:LOCATE 7,24:PRINT "THE TEMPERATURE HUMIDITY INDEX"
  477. 4770 LOCATE 8,21:PRINT "DETERMINES THE EFFECTIVE TEMPERATURE"
  478. 4780 LOCATE 11,12:INPUT "ENTER THE TEMPERATURE IN FAHRENHEIT                 ";T
  479. 4790 LOCATE 12,12:INPUT "ENTER THE RELATIVE HUMIDITY                         ";H
  480. 4800 LOCATE 15,15:PRINT "PLEASE WAIT - EFFECTIVE TEMPERATURE BEING COMPUTED"
  481. 4810 LOCATE 18,30:FOR C=1 TO 16
  482. 4820 IF CLRT$ = "Y" THEN COLOR (C):PRINT "!!!!!!!!!!!!!!!!!!!"
  483. 4830 LOCATE 18,30:C=C+1
  484. 4840 FOR Z=1 TO 400:NEXT Z
  485. 4850 NEXT C
  486. 4860 IF CLRT$ = "Y" THEN COLOR 3,0,0
  487. 4870 LOCATE 18,25:PRINT "                                   "
  488. 4880 IF H>94 THEN A=((.195*T)-15) ELSE IF H>89 AND H<95 THEN A=((.18*T)-15)
  489. 4890 IF H>79 AND H<90 THEN A=((.1667*T)-15) ELSE IF H>69 AND H<80 THEN A=((.145*T)-15)
  490. 4900 IF H>59 AND H<70 THEN A=((.1233*T)-15) ELSE IF H<60 THEN A=((.085*T)-15)
  491. 4910 TH=(((.8*T)+15)+A)
  492. 4920 IF CLRT$ = "Y" THEN COLOR 13
  493. 4930 LOCATE 20,10:PRINT "THE TEMPERATURE HUMIDITY INDEX =  ";TH;"DEGREES FAHRENHEIT"
  494. 4940 IF CLRT$ = "Y" THEN COLOR 7,0,0
  495. 4950 LOCATE 23,17:INPUT "ANOTHER TEMPERATURE HUMIDITY INDEX (Y/N)";L$
  496. 4960 IF L$="Y" OR L$="y" THEN GOTO 4710
  497. 4970 LOCATE 24,16:INPUT "View THI Explanation & Comfort Table? (Y/N)";CT$
  498. 4980 IF CT$="N" OR CT$="n" THEN GOTO 5000
  499. 4990 GOTO 5010
  500. 5000 RETURN
  501. 5010 IF CLRT$ = "Y" THEN COLOR 14,1,1
  502. 5020 CLS:PRINT "  "
  503. 5030 PRINT "    Your Temperature-Humidity Index reading was "TH"."
  504. 5040 PRINT "  "
  505. 5050 PRINT "    Readings in excess of  70  represent the point  where a few people"
  506. 5060 PRINT "    begin  to  feel  uncomfortable.   Over 75, about 1/2 of all people"
  507. 5070 PRINT "    will feel uncomfortable. Nearly all people will feel uncomfortable"
  508. 5080 PRINT "    with  readings  over  79  with rapidly  decreasing work efficiency"
  509. 5090 PRINT "    begining  with  levels  in excess of  84;  and EXTREME DANGER with"
  510. 5100 PRINT "    possibility of heat  exhaustion  and heat stroke begin with levels"
  511. 5110 PRINT "    of 92 and higher."
  512. 5120 PRINT "  "
  513. 5130 PRINT "    The THI number, used to express the  combined temperature-humidity"
  514. 5140 PRINT "    effect provides a fairly good index of equivalent heat stress.  In"
  515. 5150 PRINT "    engineering, this combined index is refered to as `effective temp-"
  516. 5160 PRINT "    erature'. The weather bureau has also been known to refer to it as"
  517. 5170 PRINT "    the Discomfort Index.  It is NOT the same as the `Heat Index' even"
  518. 5180 PRINT "    though they both help to compute `Appearant' Temperatures.
  519. 5190 PRINT "  "
  520. 5200 PRINT "  "
  521. 5210 IF CLRT$ = "Y" THEN COLOR 7,0,0
  522. 5220 RETURN
  523. 5230 REM
  524. 5240 REM     DEW POINT SUBROUTINE
  525. 5250 REM
  526. 5260 CLS:IF CLRT$ = "Y" THEN COLOR 10
  527. 5270 LOCATE 2,28:PRINT "DEW POINT CALCULATION"
  528. 5280 IF CLRT$ = "Y" THEN COLOR 5
  529. 5290 LOCATE 4,34:PRINT DATE$:LOCATE 5,35:PRINT TIME$
  530. 5300 IF CLRT$ = "Y" THEN COLOR 3,0,0
  531. 5310 KEY OFF:LOCATE 7,12
  532. 5320 INPUT "ENTER TEMPERATURE IN FAHRENHEIT                    ";T
  533. 5330 LOCATE 8,12
  534. 5340 INPUT "ENTER THE RELATIVE HUMIDITY (`50' = 50%)           ";DPRH
  535. 5350 T=(T-32)*5/9
  536. 5360 X=1-(.01*DPRH)
  537. 5370 TD=T-(14.55+.114*T)*X-((2.5+.007*T)*X)^3-(15.9+.117*T)*X^14
  538. 5380 TD=(TD*9/5)+32
  539. 5390 IF CLRT$ = "Y" THEN COLOR 3
  540. 5400 LOCATE 11,19:PRINT "PLEASE WAIT - DEW POINT BEING COMPUTED"
  541. 5410 FOR ZZ=1 TO 1600:NEXT ZZ
  542. 5420 IF CLRT$ = "Y" THEN COLOR 4
  543. 5430 LOCATE 13,23:PRINT "TF=(T-32)*5/9:X=1-(.01*DPRH)"
  544. 5440 FOR Z=1 TO 800:NEXT Z
  545. 5450 LOCATE 14,9:PRINT "TD=T-(14.55+.114*T)*X-((2.5+.007*T)*X)^3-(15.9+.117*T)*X^14"
  546. 5460 FOR ZXC=1 TO 800:NEXT ZXC
  547. 5470 LOCATE 15,30:PRINT "TD=(TD*9/5)+32"
  548. 5480 FOR ZX=1 TO 1600:NEXT ZX
  549. 5490 IF CLRT$ = "Y" THEN COLOR 13
  550. 5500 LOCATE 19,21:PRINT "DEW POINT CALCULATION = ";TD
  551. 5510 IF CLRT$ = "Y" THEN COLOR 7,0,0
  552. 5520 LOCATE 24,20:INPUT "CALCULATE ANOTHER DEW POINT (Y/N)";L$
  553. 5530 IF L$="Y" OR L$="y" THEN GOTO 5260
  554. 5540 RETURN
  555. 5550 REM     ~~~~~~~~~~LAST LINE OF PROGRAM~~~~~~~~~
  556.